home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 021 - HO Utilities - Clock Utility System.dsk / TALKING.CLOCK.bas < prev    next >
BASIC Source File  |  2019-02-16  |  3KB  |  85 lines
  1. 10  REM  APPLIED ENGINEERING TALKING CLOCK
  2. 20  GOSUB 800: REM   EXPLAIN THE PROGRAM
  3. 30  FOR I = 1 TO 2000: NEXT I
  4. 40  GOSUB 3000: REM  INSTALL TEXT-TO-SPEECH
  5. 80  HOME 
  6. 90  GOSUB 1000: REM   SEARCH SLOTS FOR A TIMEMASTER
  7. 95  HOME 
  8. 100 D$ =  CHR$(4): REM  MAKES DOS WORK
  9. 120  GOSUB 1200: REM READ THE TIME AND PARSE OUT PARTS
  10. 130  VTAB 1: IF  PEEK(49152) >127  THEN  POKE 49168,0: PRINT D$"-TTS.OFF"
  11. 140  IF X = MU  THEN 120: REM TIME HAS NOT CHANGED
  12. 150 X = MU: REM ONLY SAY THIS TIME ONCE
  13. 160  GOSUB 290: REM SAY THE TIME
  14. 170  GOTO 120
  15. 280  REM -----------------------
  16. 290  IF HU <10  THEN H$ =  STR$(HU)
  17. 380  IF HU = 10  THEN H$ = "TEN "
  18. 390  IF HU = 11  THEN H$ = "ELEVEN "
  19. 400  IF HU = 12  THEN H$ = "TWELVE "
  20. 410 MU$ =  STR$(MU): IF MU = 0  THEN MU$ = ""
  21. 420  IF MT = 0  AND MU = 0  THEN MU$ = " CLOCK"
  22. 430  IF MT = 0  THEN MT$ = "O ": GOTO 680
  23. 440  IF MT >1  THEN 640
  24. 530 MT$ = ""
  25. 540  IF MU = 0  THEN MU$ = "TEN"
  26. 550  IF MU = 1  THEN MU$ = "ELEVEN"
  27. 560  IF MU = 2  THEN MU$ = "TWELVE"
  28. 570  IF MU = 3  THEN MU$ = "THIRTEEN"
  29. 580  IF MU = 4  THEN MU$ = "4TEEN"
  30. 590  IF MU = 5  THEN MU$ = "FIFTEEN"
  31. 600  IF MU = 6  THEN MU$ = "6TEEN"
  32. 610  IF MU = 7  THEN MU$ = "7TEEN"
  33. 620  IF MU = 8  THEN MU$ = "8TEEN"
  34. 630  IF MU = 9  THEN MU$ = "9TEEN"
  35. 640  IF MT = 2  THEN MT$ = "TWENTY "
  36. 650  IF MT = 3  THEN MT$ = "THIRTY "
  37. 660  IF MT = 4  THEN MT$ = "FORTY "
  38. 670  IF MT = 5  THEN MT$ = "FIFTY "
  39. 680  VTAB 5
  40. 700  PRINT "THE TIME IS "HU":"MT;MU"   "
  41. 710  & T,"THE TIME IS " +H$ +" " +MT$ +" " +MU$: & W
  42. 720  RETURN 
  43. 799  REM -----------------------
  44. 800  REM EXPLANATION
  45. 810  TEXT : HOME 
  46. 820  PRINT "THIS PROGRAM WILL SAY THE TIME ONCE A "
  47. 830  PRINT "MINUTE. IN ORDER FOR THIS PROGRAM TO"
  48. 840  PRINT "WORK YOUR APPLE MUST HAVE A TIMEMASTER"
  49. 850  PRINT "AND A PHASOR SYNTHESIZER FROM APPLIED"
  50. 860  PRINT "ENGINEERING."
  51. 870  RETURN 
  52. 999  REM ----------------------
  53. 1000  REM  TIMEMASTER SLOT FINDER
  54. 1010 SLOT = 0
  55. 1020  FOR I = 1 TO 7
  56. 1030 ADDR = 12 *4096 +I *256: REM $CS00
  57. 1040  IF  PEEK(ADDR) = 8  AND  PEEK(ADDR +1) = 120  AND  PEEK(ADDR +254) = 178  THEN SLOT = I:I = 7
  58. 1050  NEXT 
  59. 1060 AP =  PEEK(ADDR +255)
  60. 1070  IF SLOT = 0  THEN  PRINT "TIMEMASTER II NOT IN COMPUTER.": POP : END 
  61. 1080  PRINT "YOUR TIMEMASTER II IS IN SLOT "SLOT: FOR I = 1 TO 600: NEXT : RETURN 
  62. 1199  REM ----------------------
  63. 1200  REM READ THE TIME AND PARSE PARTS
  64. 1210  PRINT D$"IN#"SLOT: PRINT D$"PR#"SLOT
  65. 1220  INPUT ":";T$
  66. 1230  PRINT D$"IN#0": PRINT D$"PR#0"
  67. 1240 HX = 12: REM ASSUMING TIMEMASTER FORMAT
  68. 1250  IF AP = 1  THEN HX = 7: REM APPLECLOCK FORMAT
  69. 1260  IF AP = 2  THEN HX = 13: REM AM/PM FORMAT
  70. 1270 HU =  VAL( MID$ (T$,HX,2))
  71. 1280  IF HU = 0  THEN HU = 12
  72. 1290  IF HU >12  THEN HU = HU -12
  73. 1300 MT =  VAL( MID$ (T$,HX +3,1))
  74. 1310 MU =  VAL( MID$ (T$,HX +4,1))
  75. 1320  RETURN 
  76. 2000  REM TEST
  77. 2010  HOME : GOSUB 3000
  78. 2020 HU = 4
  79. 2030  FOR MT = 0 TO 5: FOR MU = 0 TO 9
  80. 2040  GOSUB 280
  81. 2050  NEXT : NEXT 
  82. 2060  END 
  83. 3000  REM INSTALL TEXT-TO-SPEECH
  84. 3010 H = 30464: IF ( PEEK(116) +4) *256 + PEEK(115) = H  THEN  RETURN 
  85. 3020  PRINT  CHR$(4)"-STARTUP": END